Repository navigation
Expand file tree
/
Copy pathbuild.gradle
More file actions
132 lines (126 loc) · 4.99 KB
/
Copy pathbuild.gradle
File metadata and controls
132 lines (126 loc) · 4.99 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
import groovy.json.JsonSlurper
plugins {
id 'com.gradleup.shadow' version '9.2.2' apply false
}
def pomMetadata = new JsonSlurper().parse(file('pom.json'))
allprojects {
group = 'net.hasor'
}
subprojects {
plugins.withId('java') {
java {
toolchain.languageVersion = JavaLanguageVersion.of(17)
}
tasks.withType(JavaCompile).configureEach {
options.encoding = 'UTF-8'
options.release = 17
}
tasks.withType(Javadoc).configureEach {
options.encoding = 'UTF-8'
options.addStringOption('Xdoclint:none', '-quiet')
failOnError = false
}
tasks.withType(Test).configureEach {
useJUnitPlatform()
jvmArgs '--add-opens', 'java.base/java.lang=ALL-UNNAMED',
'--add-opens', 'java.base/java.lang.reflect=ALL-UNNAMED',
'--add-opens', 'java.base/java.io=ALL-UNNAMED',
'--add-opens', 'java.base/java.net=ALL-UNNAMED'
}
tasks.withType(GenerateModuleMetadata).configureEach {
enabled = false
}
dependencies {
testImplementation platform("org.junit:junit-bom:${property('lib.junit')}")
testImplementation 'org.junit.jupiter:junit-jupiter'
testImplementation 'org.junit.platform:junit-platform-launcher'
testRuntimeOnly 'org.slf4j:slf4j-simple:2.0.17'
}
apply plugin: 'jacoco'
jacoco {
toolVersion = property('lib.jacoco')
}
tasks.named('test') {
finalizedBy tasks.named('jacocoTestReport')
}
tasks.named('jacocoTestReport') {
dependsOn tasks.named('test')
reports {
xml.required = true
html.required = true
}
}
tasks.named('jacocoTestCoverageVerification') {
dependsOn tasks.named('test')
}
tasks.named('check') {
dependsOn tasks.named('jacocoTestReport'), tasks.named('jacocoTestCoverageVerification')
}
plugins.withId('maven-publish') {
apply plugin: 'signing'
java {
withSourcesJar()
withJavadocJar()
}
publishing {
publications {
mavenJava(MavenPublication) {
from components.java
pom {
name = providers.provider { project.findProperty('pomName') ?: project.name }
description = providers.provider { project.description ?: project.name }
url = pomMetadata.url
licenses {
pomMetadata.licenses.each { licenseMetadata ->
license {
name = licenseMetadata.name
url = licenseMetadata.url
}
}
}
developers {
pomMetadata.developers.each { developerMetadata ->
developer {
name = developerMetadata.name
email = developerMetadata.email
}
}
}
scm {
connection = pomMetadata.scm.connection
developerConnection = pomMetadata.scm.developerConnection
url = pomMetadata.scm.url
tag = pomMetadata.scm.tag
}
}
}
}
if (findProperty('centralBundleDir')) {
repositories {
maven {
name = 'centralBundle'
url = uri(findProperty('centralBundleDir'))
}
}
}
}
plugins.withId('com.gradleup.shadow') {
def publication = publishing.publications.mavenJava
publication.setArtifacts([])
publication.artifact(tasks.named('shadowJar')) {
classifier = null
}
publication.artifact(tasks.named('sourcesJar'))
publication.artifact(tasks.named('javadocJar'))
}
signing {
required { findProperty('centralRelease') == 'true' }
def key = findProperty('maven.central.signing_key')
if (key) {
useInMemoryPgpKeys(key.replace('\\n', '\n'), findProperty('maven.central.signing_password'))
}
sign publishing.publications.mavenJava
}
}
}
}