CMakeLists.txt

cmake_minimum_required(VERSION 3.16)
project(AuthForgeCPPSDK VERSION 2.0.0 LANGUAGES CXX)

include(GNUInstallDirs)
include(CMakePackageConfigHelpers)

option(AUTHFORGE_BUILD_VECTOR_GENERATOR "Build the test vector generator" OFF)
option(AUTHFORGE_BUILD_TESTS "Build the offline license file and heartbeat tests (ctest)" OFF)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

find_package(OpenSSL REQUIRED)
find_package(CURL REQUIRED)
find_package(Threads REQUIRED)

find_path(SODIUM_INCLUDE_DIR sodium.h REQUIRED)
find_library(SODIUM_LIBRARY NAMES sodium libsodium REQUIRED)

add_library(authforge_sdk authforge_sdk.cpp authforge_offline.cpp)
target_include_directories(authforge_sdk PUBLIC
  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
  $<INSTALL_INTERFACE:include>
)
target_include_directories(authforge_sdk PRIVATE ${SODIUM_INCLUDE_DIR})
target_link_libraries(authforge_sdk PUBLIC OpenSSL::Crypto CURL::libcurl Threads::Threads)
target_link_libraries(authforge_sdk PRIVATE ${SODIUM_LIBRARY})

if(WIN32)
  target_link_libraries(authforge_sdk PRIVATE iphlpapi ws2_32 advapi32)
endif()

install(
  TARGETS authforge_sdk
  EXPORT authforgeTargets
  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

install(FILES authforge_sdk.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

install(
  EXPORT authforgeTargets
  FILE AuthForgeTargets.cmake
  NAMESPACE AuthForge::
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/AuthForge
)

configure_package_config_file(
  "${CMAKE_CURRENT_SOURCE_DIR}/cmake/AuthForgeConfig.cmake.in"
  "${CMAKE_CURRENT_BINARY_DIR}/AuthForgeConfig.cmake"
  INSTALL_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/AuthForge"
)

install(
  FILES "${CMAKE_CURRENT_BINARY_DIR}/AuthForgeConfig.cmake"
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/AuthForge
)

if(AUTHFORGE_BUILD_VECTOR_GENERATOR)
  add_executable(generate_vectors generate_vectors.cpp)
  target_link_libraries(generate_vectors PRIVATE OpenSSL::Crypto)
endif()

if(AUTHFORGE_BUILD_TESTS)
  enable_testing()
  # The test includes authforge_offline.cpp directly (to reach the private
  # JSON reader for the fixture), so it compiles against authforge_sdk.cpp
  # instead of linking the library to avoid duplicate definitions.
  add_executable(offline_vectors_test tests/offline_vectors_test.cpp authforge_sdk.cpp)
  target_include_directories(offline_vectors_test PRIVATE ${CMAKE_CURRENT_SOURCE_DIR} ${SODIUM_INCLUDE_DIR})
  target_link_libraries(offline_vectors_test PRIVATE OpenSSL::Crypto CURL::libcurl Threads::Threads ${SODIUM_LIBRARY})
  if(WIN32)
    target_link_libraries(offline_vectors_test PRIVATE iphlpapi ws2_32 advapi32)
  endif()
  add_test(
    NAME offline_license_vectors
    COMMAND offline_vectors_test "${CMAKE_CURRENT_SOURCE_DIR}/offline_license_vectors.json"
  )

  # Same layout as offline_vectors_test: includes authforge_offline.cpp for
  # the JSON reader and compiles against authforge_sdk.cpp.
  add_executable(heartbeat_test tests/heartbeat_test.cpp authforge_sdk.cpp)
  target_include_directories(heartbeat_test PRIVATE ${CMAKE_CURRENT_SOURCE_DIR} ${SODIUM_INCLUDE_DIR})
  target_link_libraries(heartbeat_test PRIVATE OpenSSL::Crypto CURL::libcurl Threads::Threads ${SODIUM_LIBRARY})
  if(WIN32)
    target_link_libraries(heartbeat_test PRIVATE iphlpapi ws2_32 advapi32)
  endif()
  add_test(
    NAME heartbeat
    COMMAND heartbeat_test "${CMAKE_CURRENT_SOURCE_DIR}/test_vectors.json"
  )

  # Same layout again: self-serve offline activation (ActivateOffline) against
  # the shared vectors with a fake transport.
  add_executable(self_serve_activation_test tests/self_serve_activation_test.cpp authforge_sdk.cpp)
  target_include_directories(self_serve_activation_test PRIVATE ${CMAKE_CURRENT_SOURCE_DIR} ${SODIUM_INCLUDE_DIR})
  target_link_libraries(self_serve_activation_test PRIVATE OpenSSL::Crypto CURL::libcurl Threads::Threads ${SODIUM_LIBRARY})
  if(WIN32)
    target_link_libraries(self_serve_activation_test PRIVATE iphlpapi ws2_32 advapi32)
  endif()
  add_test(
    NAME self_serve_activation
    COMMAND self_serve_activation_test "${CMAKE_CURRENT_SOURCE_DIR}/self_serve_activation_vectors.json"
  )

  # Same layout again: HWID v2 conformance against the shared hwid_vectors.json
  # plus a macOS-only live check against the real ioreg output.
  add_executable(hwid_vectors_test tests/hwid_vectors_test.cpp authforge_sdk.cpp)
  target_include_directories(hwid_vectors_test PRIVATE ${CMAKE_CURRENT_SOURCE_DIR} ${SODIUM_INCLUDE_DIR})
  target_link_libraries(hwid_vectors_test PRIVATE OpenSSL::Crypto CURL::libcurl Threads::Threads ${SODIUM_LIBRARY})
  if(WIN32)
    target_link_libraries(hwid_vectors_test PRIVATE iphlpapi ws2_32 advapi32)
  endif()
  add_test(
    NAME hwid_vectors
    COMMAND hwid_vectors_test "${CMAKE_CURRENT_SOURCE_DIR}/hwid_vectors.json"
  )
endif()